archetype (adl_version=1.4; uid=7ca560c1-666f-4eb3-b553-0e0f1cc20449)
	openEHR-EHR-EVALUATION.living_arrangement.v0

concept
	[at0000]	-- Living arrangement
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Atomica Informatics">
		["email"] = <"heather.leslie@atomicainformatics.com">
		["date"] = <"2018-05-29">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record the circumstances about how an individual lives alone or with others.">
			use = <"Use to record the circumstances about how an individual lives alone or with others. 

The intent of this archetype is to provide a sense of the level of day-to-day support, both physically and emotionally, that may be available to an individual in their 'home' setting.

The concepts around housing, accommodation and living arrangements are complex and often potentially overlapping. Within this archetype, the intent of the concept of 'household' is to capture information about the group of people (one or more) who live in the same dwelling and share meals or living accommodation. A single dwelling may be considered to contain multiple households if either meals or living space are not shared. In this context households can include varieties of blended families, share housing, group homes, boarding houses, and a single room occupancy.

This archetype has been designed to be used within the EVALUATION.housing_summary archetype, but may be used within any other appropriate ENTRY or CLUSTER archetype related to recording social context.">
			keywords = <"alone", "solo", "family", "friends", "others", "household">
			misuse = <"Not to be used to record details about the physical structure in which an individual lives - use CLUSTER.dwelling for this purpose.

Not to be used to record details about the setting in which an individual usually resides - use CLUSTER.accommodation for this purpose.">
			copyright = <"© openEHR Foundation, Apperta Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <"John Tore Valand, Helse Bergen, Norway", "Vebjørn Arntzen, Oslo University Hospital, Norway", "Silje Ljosland Bakke, Nasjonal IKT HF, Norway", "Nyree Taylor, Ocean Informatics, Australia">
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/3.0/.">
		["custodian_organisation"] = <"Apperta UK">
		["references"] = <"Derived from: Household, Draft Archetype [Internet]. Australian Digital Health Agency, Australian Digital Health Agency Clinical Knowledge Manager. No longer available.

National Housing and Homelessness Data Dictionary [Internet]. Canberra, Australia: Australian Institute of Health and Welfare (AIHW); 2013 [cited 2018 May 30]. Version 1. Cat. no. HOU 269. Available from: https://www.aihw.gov.au/getmedia/a47d4c86-a8aa-4f00-a889-42edea09cc2f/17841.pdf">
		["current_contact"] = <"Heather Leslie, Atomica Informatics<heather.leslie@atomicainformatics.com>">
		["original_namespace"] = <"uk.org.clinicalmodels">
		["original_publisher"] = <"Apperta UK">
		["custodian_namespace"] = <"uk.org.clinicalmodels">
		["MD5-CAM-1.0.1"] = <"CD002BB574656EC690FA866E32730BFE">
		["build_uid"] = <"c553b0ae-6efd-47b7-ba8d-265b93d7dd6e">
		["revision"] = <"0.0.1-alpha">
	>

definition
	EVALUATION[at0000] matches {    -- Living arrangement
		data matches {
			ITEM_TREE[at0001] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0003] occurrences matches {0..1} matches {    -- Description
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0004] occurrences matches {0..1} matches {    -- Living arrangement
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0005] occurrences matches {0..1} matches {    -- Household composition
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0006] occurrences matches {0..1} matches {    -- Household description
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0007] occurrences matches {0..1} matches {    -- Number of household members
						value matches {
							DV_COUNT matches {*}
						}
					}
					allow_archetype CLUSTER[at0008] occurrences matches {0..*} matches {    -- Additional details
						include
							archetype_id/value matches {/.*/}
					}
					ELEMENT[at0009] occurrences matches {0..1} matches {    -- Pets
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0010] occurrences matches {0..1} matches {    -- Comment
						value matches {
							DV_TEXT matches {*}
						}
					}
				}
			}
		}
		protocol matches {
			ITEM_TREE[at0002] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0012] occurrences matches {0..1} matches {    -- Last updated
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					allow_archetype CLUSTER[at0011] occurrences matches {0..*} matches {    -- Extension
						include
							archetype_id/value matches {/.*/}
					}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Living arrangement">
					description = <"The circumstances about an individual living alone or with others.">
					comment = <"This information will provide a sense of the level of support, both physically and emotionally, to which an individual may have access.">
				>
				["at0001"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0003"] = <
					text = <"Description">
					description = <"Narrative description about the living arrangements.">
				>
				["at0004"] = <
					text = <"Living arrangement">
					description = <"Single word or phrase that describes if an individual usually resides alone or with others.">
					comment = <"Coding of the living arrangement with a terminology is preferred, where possible. The value sets for this data element are likely to vary between jurisdictions - it is anticipated that they will usually be set within a use-case specific template. For example: 'lives alone'; 'lives with family'; or 'lives with others'.">
				>
				["at0005"] = <
					text = <"Household composition">
					description = <"Single word or phrase that describes the relationship between people who reside together.">
					comment = <"Coding of the household composition with a terminology is preferred, where possible. For example: single; sole parent with children aged less than 16 years; couple; couple with children aged less than 16 years; family; family with other non-related members present; or group of unrelated adults.">
				>
				["at0006"] = <
					text = <"Household description">
					description = <"Narrative description about the relationship between people who reside together.">
				>
				["at0007"] = <
					text = <"Number of household members">
					description = <"The number of individuals who are in the household.">
				>
				["at0008"] = <
					text = <"Additional details">
					description = <"Further details about the living arrangement.">
					comment = <"This SLOT may be used to nest additional archetypes describing additional details about living arrangements that may be local to a jurisdiction.">
				>
				["at0009"] = <
					text = <"Pets">
					description = <"Narrative description about the pets who reside with an individual.">
				>
				["at0010"] = <
					text = <"Comment">
					description = <"Additional narrative about the living arrangement not captured in other fields.">
				>
				["at0011"] = <
					text = <"Extension">
					description = <"Additional information required to extend the model with local content or to align with other reference models/formalisms.">
					comment = <"For example: local information requirements; or additional metadata to align with FHIR.">
				>
				["at0012"] = <
					text = <"Last updated">
					description = <"The date this summary was last updated.">
				>
			>
		>
	>