archetype (adl_version=1.4; uid=dd5b70b5-0d51-49fa-b94f-f8bf1d750d9c)
	openEHR-EHR-EVALUATION.legal_directive.v0

concept
	[at0000]	-- Legal directive
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Heidi Koikkalainen">
		["organisation"] = <"NES Digital Service, Edinburgh Napier University">
		["email"] = <"hk.koikkalainen@gmail.com">
		["date"] = <"2019-10-23">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"A framework to communicate any legal directives that apply or have applied to the person.">
			use = <"A framework to communicate any legal directives that apply or have applied to the person.">
			keywords = <"legal, power, attorney, welfare, guardian, guardianship, representative", ...>
			misuse = <"">
			copyright = <"© openEHR Foundation, Apperta Foundation, Apperta Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <"Ian McNicoll, freshEHR Clinical Informatics, United Kingdom", "Vebjørn Arntzen, Oslo University Hospital, Norway">
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/3.0/.">
		["custodian_organisation"] = <"Apperta UK">
		["references"] = <"">
		["current_contact"] = <"Heidi Koikkalainen, hk.koikkalainen@gmail.com">
		["original_namespace"] = <"uk.org.clinicalmodels">
		["original_publisher"] = <"Apperta UK">
		["custodian_namespace"] = <"uk.org.clinicalmodels">
		["MD5-CAM-1.0.1"] = <"436127DB76375CBF3FBEABE762460662">
		["build_uid"] = <"bef67b45-e540-46aa-968a-91205028feb3">
		["revision"] = <"0.0.1-alpha">
	>

definition
	EVALUATION[at0000] matches {    -- Legal directive
		data matches {
			ITEM_TREE[at0001] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0005] occurrences matches {0..1} matches {    -- Type of directive
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0004] occurrences matches {0..1} matches {    -- Status
						value matches {
							DV_CODED_TEXT matches {
								defining_code matches {
									[local::
									at0044,    -- Present
									at0045,    -- Absent
									at0047]    -- Unknown
								}
							}
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0006] occurrences matches {0..1} matches {    -- Description
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0007] occurrences matches {0..*} matches {    -- Condition
						value matches {
							DV_TEXT matches {*}
						}
					}
					allow_archetype CLUSTER[at0052] occurrences matches {0..*} matches {    -- Directive details
						include
							archetype_id/value matches {/.*/}
					}
					CLUSTER[at0058] occurrences matches {0..*} matches {    -- Location details
						items cardinality matches {1..*; unordered} matches {
							ELEMENT[at0030] occurrences matches {0..1} matches {    -- Location
								value matches {
									DV_TEXT matches {*}
								}
							}
							allow_archetype CLUSTER[at0059] occurrences matches {0..1} matches {    -- Person
								include
									archetype_id/value matches {/.*/}
							}
							allow_archetype CLUSTER[at0060] occurrences matches {0..1} matches {    -- Multimedia representation
								include
									archetype_id/value matches {/openEHR-EHR-CLUSTER\.multimedia\.v0/}
							}
						}
					}
					ELEMENT[at0038] occurrences matches {0..1} matches {    -- Comment
						value matches {
							DV_TEXT matches {*}
						}
					}
				}
			}
		}
		protocol matches {
			ITEM_TREE[at0010] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0053] occurrences matches {0..1} matches {    -- Valid period start
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					ELEMENT[at0054] occurrences matches {0..1} matches {    -- Valid period end
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					ELEMENT[at0056] occurrences matches {0..1} matches {    -- Review due date
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					ELEMENT[at0055] occurrences matches {0..1} matches {    -- Last updated
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					allow_archetype CLUSTER[at0025] occurrences matches {0..*} matches {    -- Witness
						include
							archetype_id/value matches {/.*/}
					}
					ELEMENT[at0027] occurrences matches {0..*} matches {    -- Mandate
						value matches {
							DV_TEXT matches {*}
							DV_URI matches {*}
						}
					}
					allow_archetype CLUSTER[at0061] occurrences matches {0..*} matches {    -- Extension
						include
							archetype_id/value matches {/.*/}
					}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Legal directive">
					description = <"A framework to communicate any legal directives that apply or have applied to the person.">
				>
				["at0001"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0004"] = <
					text = <"Status">
					description = <"The status of the legal directive.">
					comment = <"Coding of the legal directive status with a terminology is preferred, where possible.">
				>
				["at0005"] = <
					text = <"Type of directive">
					description = <"The type of legal directive.">
					comment = <"A short text description of the nature of the legal directive. Coding of the type of directive with a terminology is preferred, where possible. It is expected that this is largely localised to reflect local policy and legislation.

For example, in the Netherlands, advance care directive types include, but are not limited to, 'Treatment prohibition', 'Treatment prohibition with completion of Completed Life', 'Euthanasia request' and 'Declaration of life'.

In the UK, advance care directive types include 'Advance Decision', 'Advance Directive' and 'Advance Statement'.">
				>
				["at0006"] = <
					text = <"Description">
					description = <"Narrative description of the overall legal directive.">
					comment = <"May be used to record a narrative overview of the complete legal directive, which may or may not be supported by structured data. Details of specific structured findings can be included using CLUSTER archetypes in the 'Directive details' slot. This data element may be used to capture legacy data that is not available in a structured format.">
				>
				["at0007"] = <
					text = <"Condition">
					description = <"The conditions or situations in which the individual wishes the legal directive to apply.">
				>
				["at0010"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0025"] = <
					text = <"Witness">
					description = <"Personal details of a person who witnesses the completion of the legal directive.">
					comment = <"For example, 'John Smith, Lawyer'.">
				>
				["at0027"] = <
					text = <"Mandate">
					description = <"Description of any legislation or other authoritative guidance that apply.">
				>
				["at0030"] = <
					text = <"Location">
					description = <"Information regarding where the legal directive is stored and how to gain access to it.">
					comment = <"For example, 'In the top drawer of the bedside table'.">
				>
				["at0038"] = <
					text = <"Comment">
					description = <"Additional narrative about the legal directive not captured in other fields.">
				>
				["at0044"] = <
					text = <"Present">
					description = <"The individual has a legal directive.">
				>
				["at0045"] = <
					text = <"Absent">
					description = <"The individual does not have a legal directive.">
				>
				["at0047"] = <
					text = <"Unknown">
					description = <"It is not known whether the individual has a legal directive.">
				>
				["at0052"] = <
					text = <"Directive details">
					description = <"Slot to include CLUSTER archetypes containing specific details about the legal directive decisions as per national or other local requirements.">
				>
				["at0053"] = <
					text = <"Valid period start">
					description = <"The date/time that marks the beginning of the valid period of time for this legal directive.">
				>
				["at0054"] = <
					text = <"Valid period end">
					description = <"The date/time that marks the conclusion of the valid period of time for this legal directive.">
					comment = <"'Valid period end' may often overlap with 'Review due date'. However, they may need to be recorded separately in circumstances where a document has an extended period of validity but requires an interim review. That may be due to changed personal circumstances/events or local policy.">
				>
				["at0055"] = <
					text = <"Last updated">
					description = <"The date when this legal directive record was last updated. This may not be a formal review but e.g. a typo correction.">
				>
				["at0056"] = <
					text = <"Review due date">
					description = <"The date at which the legal directive is due to be reviewed.">
					comment = <"'Valid period end' may often overlap with 'Review due date'. However, they may need to be recorded separately in circumstances where a document has an extended period of validity but requires an interim review. That may be due to changed personal circumstances/events or local policy.">
				>
				["at0058"] = <
					text = <"Location details">
					description = <"Information regarding where the legal directive is stored and who has a copy of it.">
				>
				["at0059"] = <
					text = <"Person">
					description = <"Details of a person who has a copy of the legal directive.">
					comment = <"For example, 'John Smith, Lawyer'.">
				>
				["at0060"] = <
					text = <"Multimedia representation">
					description = <"Digital image, video or diagram representing the legal directive.">
					comment = <"For example, 'www.dropbox.com/mylegaldirective'.">
				>
				["at0061"] = <
					text = <"Extension">
					description = <"Additional information required to extend the model with local content or to align with other reference models/formalisms.">
					comment = <"For example: local information requirements; or additional metadata to align with FHIR.">
				>
			>
		>
	>