archetype (adl_version=1.4; uid=38b179e2-61f8-45f3-997b-6b39cce32021)
	openEHR-EHR-EVALUATION.alert.v0

concept
	[at0000]	-- Alert
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"John Meredith">
		["organisation"] = <"Digital Health and Care Wales">
		["email"] = <"john.meredith@wales.nhs.uk">
		["date"] = <"2021-06-08">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"For the recording of an alert which describes a clinical or administrative fact brought to the attention of the users of the clinical systems that is to be taken into account when shaping diagnostic and therapeutic policy or in dealing with the patient, usually because of a safety risk.">
			use = <"">
			keywords = <"alert, warnings", ...>
			misuse = <"Not to be used for recording of conditions. Conditions or other problems to which the alert pertains should be referenced within an appropriate problem list or similar structure.">
			copyright = <"© Apperta Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <"Based upon Health and Care Information models (HCIM) by Nictiz (https://www.nictiz.nl/)", ...>
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 4.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/4.0/.">
		["custodian_organisation"] = <"Apperta UK">
		["references"] = <"Based upon ZIBS Alert-v4.1(2020EN), https://zibs.nl/wiki/Alert-v4.1(2020EN)">
		["original_namespace"] = <"uk.org.clinicalmodels">
		["original_publisher"] = <"Apperta UK">
		["custodian_namespace"] = <"uk.org.clinicalmodels">
		["MD5-CAM-1.0.1"] = <"73CC9971117F9341FAA375633E598746">
		["build_uid"] = <"51c3cc48-aa0f-4e7e-9423-4411dc1875fd">
		["revision"] = <"0.0.1-alpha">
	>

definition
	EVALUATION[at0000] matches {    -- Alert
		data matches {
			ITEM_TREE[at0001] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0002] matches {    -- Alert or warning name
						value matches {
							DV_TEXT matches {*}
							DV_CODED_TEXT matches {*}
						}
					}
					ELEMENT[at0017] occurrences matches {0..1} matches {    -- Status
						value matches {
							DV_CODED_TEXT matches {
								defining_code matches {
									[local::
									at0018,    -- active
									at0020,    -- inactive
									at0021]    -- entered-in-error
								}
							}
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0003] occurrences matches {0..1} matches {    -- Alert or warning start
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					ELEMENT[at0004] occurrences matches {0..1} matches {    -- Alert or warning end
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					ELEMENT[at0007] occurrences matches {0..1} matches {    -- Comment
						value matches {
							DV_TEXT matches {*}
						}
					}
				}
			}
		}
		protocol matches {
			ITEM_TREE[at0008] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					allow_archetype CLUSTER[at0009] occurrences matches {0..*} matches {    -- Extension
						include
							archetype_id/value matches {/.*/}
					}
					ELEMENT[at0010] matches {    -- Last updated
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
					ELEMENT[at0022] occurrences matches {0..1} matches {    -- Next review date
						value matches {
							DV_DATE_TIME matches {*}
						}
					}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Alert">
					description = <"An alert or warning entry describes a clinical or administrative fact brought to the attention of the users of the clinical systems to be taken into account when shaping diagnostic and therapeutic policy or in dealing with the patient, usually because of a safety risk.">
				>
				["at0001"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0002"] = <
					text = <"Alert or warning name">
					description = <"A warning, other than a condition or problem. For example, a patient can be given an ‘Aggressive patient' alert.
The warning can be entered in code (there are codes for frequently used alerts), but seeing the dynamic nature of the warnings cf. SARS and Ebola, these alerts will often be entered as free text.">
				>
				["at0003"] = <
					text = <"Alert or warning start">
					description = <"The date and time at which the described alert was entered as a warning.
This can be an exact date and time, or a rough indication of the date (such as only the year, or the month and the year).">
				>
				["at0004"] = <
					text = <"Alert or warning end">
					description = <"The date and time at which the described alert was retracted as a warning.
This can be an exact date and time, or a rough indication of the date (such as only the year, or the month and the year).">
				>
				["at0007"] = <
					text = <"Comment">
					description = <"Explanatory comments to the alert that can not be expressed in any of the other elements.">
				>
				["at0008"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0009"] = <
					text = <"Extension">
					description = <"">
				>
				["at0010"] = <
					text = <"Last updated">
					description = <"">
				>
				["at0017"] = <
					text = <"Status">
					description = <"References HL7 FHIR Alert-status ValueSet as a terminology binding (http://hl7.org/implement/standards/fhir/2015Jan/alert-status.html).">
				>
				["at0018"] = <
					text = <"active">
					description = <"A current alert that should be displayed to a user. A system may use the category to determine which roles should view the alert.">
				>
				["at0020"] = <
					text = <"inactive">
					description = <"The alert does not need to be displayed any more.">
				>
				["at0021"] = <
					text = <"entered-in-error">
					description = <"The alert was added in error, and should no longer be displayed.">
				>
				["at0022"] = <
					text = <"Next review date">
					description = <"">
				>
			>
		>
	>