archetype (adl_version=1.4; uid=7ec3d7ad-c115-4211-9795-c1a8bd3c1aa3)
	openEHR-EHR-CLUSTER.contact_cc.v0

concept
	[at0000]	-- Contact
language
	original_language = <[ISO_639-1::en]>
description
	original_author = <
		["name"] = <"Hildegard McNicoll">
		["organisation"] = <"freshEHR Clinical Informatics Ltd.">
		["email"] = <"hildi@freshehr.com">
		["date"] = <"2018-07-19">
	>
	details = <
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"For the purpose of capturing patient amd organisation contact information.">
			use = <"Use to record patient contact information in line with the corresponding FHIR resource.

The slots for name, telecom, organisation and address should be filled with the appropriate FHIR resource-aligned cluster archetypes.">
			misuse = <"Do not use for recording practitioner information. Use the CLUSTER.fhir_practitioner for that purpose.">
			copyright = <"© Apperta Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <>
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 3.0 License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/3.0/.">
		["custodian_organisation"] = <"Apperta UK">
		["references"] = <"https://fhir.hl7.org.uk/STU3/StructureDefinition/CareConnect-Patient-1 cited 19-Jul-2018.">
		["current_contact"] = <"Hildegard McNicoll, freshEHR Clinical Informatics Ltd.<hildi@freshehr.com>">
		["original_namespace"] = <"uk.org.clinicalmodels">
		["original_publisher"] = <"Apperta UK">
		["custodian_namespace"] = <"uk.org.clinicalmodels">
		["MD5-CAM-1.0.1"] = <"A92FD95229E77F51F656499514C2F522">
		["build_uid"] = <"b8c22650-2ea2-4da8-a4f1-73970b2a83f4">
		["revision"] = <"0.0.1-alpha">
	>

definition
	CLUSTER[at0000] matches {    -- Contact
		items cardinality matches {1..*; unordered} matches {
			ELEMENT[at0001] occurrences matches {0..1} matches {    -- Relationship
				value matches {
					DV_TEXT matches {*}
				}
			}
			ELEMENT[at0013] occurrences matches {0..1} matches {    -- Purpose
				value matches {
					DV_TEXT matches {*}
				}
			}
			allow_archetype CLUSTER[at0002] occurrences matches {0..*} matches {    -- Name
				include
					archetype_id/value matches {/openEHR-EHR-CLUSTER\.fhir_name(-[a-zA-Z0-9_]+)*\.v0/}
			}
			allow_archetype CLUSTER[at0003] occurrences matches {0..*} matches {    -- Telecoms
				include
					archetype_id/value matches {/openEHR-EHR-CLUSTER\.fhir_telecom(-[a-zA-Z0-9_]+)*\.v0/}
			}
			allow_archetype CLUSTER[at0004] occurrences matches {0..*} matches {    -- Address
				include
					archetype_id/value matches {/openEHR-EHR-CLUSTER\.fhir_address(-[a-zA-Z0-9_]+)*\.v0/}
			}
			ELEMENT[at0005] occurrences matches {0..1} matches {    -- Gender
				value matches {
					DV_CODED_TEXT matches {
						defining_code matches {
							[local::
							at0006,    -- Male
							at0007,    -- Female
							at0008,    -- Other
							at0009]    -- Unknown
						}
					}
				}
			}
			allow_archetype CLUSTER[at0010] occurrences matches {0..*} matches {    -- Organisation
				include
					archetype_id/value matches {/openEHR-EHR-CLUSTER\.fhir_organisation(-[a-zA-Z0-9_]+)*\.v0/}
			}
			ELEMENT[at0011] occurrences matches {0..1} matches {    -- Valid period start
				value matches {
					DV_DATE_TIME matches {*}
				}
			}
			ELEMENT[at0012] occurrences matches {0..1} matches {    -- Valid period end
				value matches {
					DV_DATE_TIME matches {*}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"Contact">
					description = <"Contacts for patients and organisations (excluding practitioners).">
				>
				["at0001"] = <
					text = <"Relationship">
					description = <"The relationship between the subject and the contact. This field is only appropriate when the archetype is used for patient contacts, not for organisation contacts.">
					comment = <"Coding with a terminology is desirable where possible.">
				>
				["at0002"] = <
					text = <"Name">
					description = <"Name details for the contact.">
				>
				["at0003"] = <
					text = <"Telecoms">
					description = <"Telecoms details for the contact.">
				>
				["at0004"] = <
					text = <"Address">
					description = <"Address details for the contact.">
				>
				["at0005"] = <
					text = <"Gender">
					description = <"Gender details for the contact.">
				>
				["at0006"] = <
					text = <"Male">
					description = <"The contact's gender is male.">
				>
				["at0007"] = <
					text = <"Female">
					description = <"The contact's gender is female.">
				>
				["at0008"] = <
					text = <"Other">
					description = <"The contact's gender is other.">
				>
				["at0009"] = <
					text = <"Unknown">
					description = <"The contact's gender is unknown.">
				>
				["at0010"] = <
					text = <"Organisation">
					description = <"Reference to organisation details for the contact.">
				>
				["at0011"] = <
					text = <"Valid period start">
					description = <"Date and time when contact detail starts to be valid.">
				>
				["at0012"] = <
					text = <"Valid period end">
					description = <"Date and time when contact detail stops being valid.">
				>
				["at0013"] = <
					text = <"Purpose">
					description = <"Indicates a purpose for which the contact can be reached. This field is only appropriate when the archetype is used inside an organisation cluster.">
				>
			>
		>
	>