archetype (adl_version=1.4; uid=421e31a0-77e2-4fe8-95e1-91fdcf33786b)
	openEHR-EHR-EVALUATION.adl.v0

concept
	[at0000]	-- ADL activity summary
language
	original_language = <[ISO_639-1::en]>
	translations = <
		["nb"] = <
			language = <[ISO_639-1::nb]>
			author = <
				["name"] = <"Silje Ljosland Bakke">
				["organisation"] = <"Helse Vest IKT AS">
				["email"] = <"silje.ljosland.bakke@helse-vest-ikt.no">
			>
		>
	>
description
	original_author = <
		["name"] = <"Heather Leslie">
		["organisation"] = <"Atomica Informatics">
		["email"] = <"heather.leslie@atomicainformatics.com">
		["date"] = <"2020-10-26">
	>
	details = <
		["nb"] = <
			language = <[ISO_639-1::nb]>
			purpose = <"For å registrere et sammendrag eller varig (persistent) informasjon om et individs evne til å utføre en spesifisert aktivitet i dagliglivet.">
			use = <"Brukes for å registrere et sammendrag eller varig (persistent) informasjon om et individs evne til å utføre en spesifisert aktivitet i dagliglivet.

Denne arketypen er laget for å kunne brukes i en rekke forskjellige kontekster. Eksempler kan være å registrere en vurdering av ADL-ferdigheter under en klinisk konsultasjon, en del av en behandlingsplan, eller som en oppsummering innenfor en innleggelses- eller utskrivingsrapport. Det er meningen at det skal brukes én instans av arketypen for hver spesifikke ADL-aktivitet.">
			misuse = <"Brukes ikke til å registrere resultatene av formelle kartleggingsverktøy, skåringer eller skalaer for vurdering av ADL-ferdigheter, for eksempel Barthel indeks. Bruk spesifikke arketyper for hver skår eller skala, for eksempel OBSERVATION.modified_barthel_index.">
			copyright = <"© openEHR Foundation">
		>
		["en"] = <
			language = <[ISO_639-1::en]>
			purpose = <"To record summary information about an individual's ability to perform an identified activity of daily living.">
			use = <"Use to record summary information about an individual's ability to perform an identified activity of daily living.

This archetype has been designed to be used in a variety of contexts. For example, recording an ADL assessment during a clinical consultation; as part of a persistent care plan; or to provide a summary statement within a nursing admission or discharge report. It is intended to be instantiated once for each identified ADL activity.">
			misuse = <"Not to be used to record the results of formal instruments, scores or scales, assessing capability for activities of daily living, such as the Barthel Index - use specific archetypes for each score or scale, such as OBSERVATION.modified_barthel_index.">
			copyright = <"© openEHR Foundation">
		>
	>
	lifecycle_state = <"in_development">
	other_contributors = <>
	other_details = <
		["licence"] = <"This work is licensed under the Creative Commons Attribution-ShareAlike 4.0 International License. To view a copy of this license, visit http://creativecommons.org/licenses/by-sa/4.0/.">
		["custodian_organisation"] = <"openEHR Foundation">
		["current_contact"] = <"Heather Leslie, Atomica Informatics, Australia">
		["original_namespace"] = <"org.openehr">
		["original_publisher"] = <"openEHR Foundation">
		["custodian_namespace"] = <"org.openehr">
		["MD5-CAM-1.0.1"] = <"DFDDD6C25F0EA09E352C190D03AC813A">
		["build_uid"] = <"a69e5c55-20f8-4f32-b71d-79c0ec69802f">
		["revision"] = <"0.0.1-alpha">
	>

definition
	EVALUATION[at0000] matches {    -- ADL activity summary
		data matches {
			ITEM_TREE[at0003] matches {    -- Tree
				items cardinality matches {0..*; unordered} matches {
					ELEMENT[at0004] matches {    -- Activity name
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0005] occurrences matches {0..1} matches {    -- Clinical description
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0006] occurrences matches {0..1} matches {    -- Capability
						value matches {
							DV_CODED_TEXT matches {
								defining_code matches {
									[local::
									at0007,    -- Independent
									at0008,    -- Independent with equipment
									at0009,    -- Requires assistance
									at0010,    -- Dependent
									at0019]    -- Not applicable
								}
							}
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0018] occurrences matches {0..*} matches {    -- Limitation
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0011] occurrences matches {0..1} matches {    -- Support description
						value matches {
							DV_TEXT matches {*}
						}
					}
					ELEMENT[at0012] occurrences matches {0..1} matches {    -- Equipment description
						value matches {
							DV_TEXT matches {*}
						}
					}
					allow_archetype CLUSTER[at0013] occurrences matches {0..*} matches {    -- Equipment
						include
							archetype_id/value matches {/openEHR-EHR-CLUSTER\.device(-[a-zA-Z0-9_]+)*\.v1/}
					}
					allow_archetype CLUSTER[at0014] occurrences matches {0..*} matches {    -- Additional details
						include
							archetype_id/value matches {/.*/}
					}
					ELEMENT[at0015] occurrences matches {0..1} matches {    -- Comment
						value matches {
							DV_TEXT matches {*}
						}
					}
				}
			}
		}
		protocol matches {
			ITEM_TREE[at0016] matches {    -- Item tree
				items cardinality matches {0..*; unordered} matches {
					allow_archetype CLUSTER[at0017] occurrences matches {0..*} matches {    -- Extension
						include
							archetype_id/value matches {/.*/}
					}
				}
			}
		}
	}


ontology
	term_definitions = <
		["en"] = <
			items = <
				["at0000"] = <
					text = <"ADL activity summary">
					description = <"Summary information about an individual's ability to perform an identified activity of daily living.">
				>
				["at0003"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0004"] = <
					text = <"Activity name">
					description = <"The name of the activity of daily living.">
					comment = <"For example: movement in bed; transfers; locomotion; dressing; personal hygiene; and feeding">
				>
				["at0005"] = <
					text = <"Clinical description">
					description = <"Narrative description about the individual's ability to perform the activity.">
				>
				["at0006"] = <
					text = <"Capability">
					description = <"Category of the ability for the individual to perform the identified activity.">
				>
				["at0007"] = <
					text = <"Independent">
					description = <"The individual is able to perform the activity independently.">
				>
				["at0008"] = <
					text = <"Independent with equipment">
					description = <"The individual is able to perform the activity with the assistance of equipment or aids.">
				>
				["at0009"] = <
					text = <"Requires assistance">
					description = <"The individual requires active support to perform the activity.">
				>
				["at0010"] = <
					text = <"Dependent">
					description = <"The individual is not able to perform the activity by themselves.">
				>
				["at0011"] = <
					text = <"Support description">
					description = <"Description about the support required to carry out the activity.">
				>
				["at0012"] = <
					text = <"Equipment description">
					description = <"Description about the equipment or aide required to carry out the activity.">
				>
				["at0013"] = <
					text = <"Equipment">
					description = <"Structured details about the equipment required.">
				>
				["at0014"] = <
					text = <"Additional details">
					description = <"Additional structured details about the ability to perform the activity.">
				>
				["at0015"] = <
					text = <"Comment">
					description = <"Additional narrative about the individual's ability to perform the activity not captured in other fields.">
				>
				["at0016"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0017"] = <
					text = <"Extension">
					description = <"Additional information required to extend the model with local content or to align with other reference models or formalisms.">
					comment = <"For example: local information requirements; or additional metadata to align with FHIR.">
				>
				["at0018"] = <
					text = <"Limitation">
					description = <"A limitation of the individual in carrying out the identified activity.">
					comment = <"For example: 'Difficulty holding drinks' or 'Difficulty cutting up food'.">
				>
				["at0019"] = <
					text = <"Not applicable">
					description = <"Assessment of the activity is not applicable to the individual.">
				>
			>
		>
		["nb"] = <
			items = <
				["at0000"] = <
					text = <"ADL-aktivitetssammendrag">
					description = <"Sammendrag eller varig (persistent) informasjon om et individs evne til å utføre en spesifisert aktivitet i dagliglivet.">
				>
				["at0003"] = <
					text = <"Tree">
					description = <"@ internal @">
				>
				["at0004"] = <
					text = <"Aktivitetsnavn">
					description = <"Navnet på ADL-aktiviteten.">
					comment = <"For eksempel bevegelighet i seng, overføring, mobilitet, påkledning, personlig hygiene eller spising.">
				>
				["at0005"] = <
					text = <"Klinisk beskrivelse">
					description = <"Fritekstbeskrivelse av individets evne til å utføre aktiviteten.">
				>
				["at0006"] = <
					text = <"Evne">
					description = <"Kategorisering av individets evne til å utføre aktiviteten.">
				>
				["at0007"] = <
					text = <"Selvstendig">
					description = <"Individet kan utføre aktiviteten selvstendig.">
				>
				["at0008"] = <
					text = <"Selvstendig med hjelpemidler">
					description = <"Individet kan utføre aktiviteten selvstendig ved hjelp av hjelpemidler.">
				>
				["at0009"] = <
					text = <"Trenger assistanse">
					description = <"Individet trenger aktiv assistanse for å utføre aktiviteten.">
				>
				["at0010"] = <
					text = <"Helt hjelpetrengende">
					description = <"Individet kan ikke utføre aktiviteten uten omfattende hjelp.">
				>
				["at0011"] = <
					text = <"Beskrivelse av hjelpebehov">
					description = <"Beskrivelse av hjelpen individet trenger for å utføre aktiviteten.">
				>
				["at0012"] = <
					text = <"Beskrivelse av hjelpemidler">
					description = <"Beskrivelse av hjelpemidler eller utstyr individet trenger for å utføre aktiviteten.">
				>
				["at0013"] = <
					text = <"Utstyr">
					description = <"Strukturerte detaljer om utstyret.">
				>
				["at0014"] = <
					text = <"Ytterligere detaljer.">
					description = <"Ytterligere strukturerte detaljer om individets evne til å utføre aktiviteten.">
				>
				["at0015"] = <
					text = <"Kommentar">
					description = <"Ytterligere fritekst om individets evne til å utføre aktiviteten, som ikke fanges opp av andre felt.">
				>
				["at0016"] = <
					text = <"Item tree">
					description = <"@ internal @">
				>
				["at0017"] = <
					text = <"Tilleggsinformasjon">
					description = <"Ytterligere informasjon som trengs for å kunne registrere lokalt definert innhold eller for å tilpasse til andre referansemodeller/formalismer.">
					comment = <"For eksempel lokale informasjonsbehov eller ytterligere metadata for å kunne tilpasse til tilsvarende konsepter i FHIR.">
				>
				["at0018"] = <
					text = <"Begrensning">
					description = <"En begrensning individet har i utførelsen av den spesifiserte aktiviteten.">
					comment = <"For eksempel: \"Vanskeligheter med å holde drikkeglass\" eller \"Vanskeligheter med å skjære opp mat\".">
				>
				["at0019"] = <
					text = <"Ikke aktuelt">
					description = <"Den angitte aktiviteten er ikke aktuell for individet.">
				>
			>
		>
	>